C ZONECHANGE.F - FOR CHANGING ZONE 54 DATA TO ZONE 55 BY TRIMMING OFF
C ALL 0 COORDS THEN CONVERTING TO LAT/LONG THEN TRIMMING ALL LONGS .LT. 142
C THEN CONVERT TO AMG IN ZONE 55
      CHARACTER*24 FRONT
      CHARACTER* 32 BACK
      INTEGER*4 EAST,NORTH
      REAL*8 XEAST,XNORTH,LAT,LON
      OPEN(UNIT=3,FILE='bass54.ldt',READONLY)
      OPEN(UNIT=4,FILE='bass54.dat')
   10 READ(3,100,END=20) FRONT,EAST,NORTH,BACK
      IF (EAST .EQ. 0 .OR. NORTH .EQ. 0) GOTO 10
C SKIP BLANKS
      XEAST=EAST
      XNORTH=NORTH
      CALL GEOGRF(XEAST,XNORTH,LAT,LON)
C CONVERT TO LAT LONG IN ZONE 54
      IF (LON .LT. 142.0D00) GOTO 10
C TOO FAR WEST
      CALL GEOUTM(LAT,LON,XEAST,XNORTH)
C CONVERT TO AMG IN ZONE55
      EAST=XEAST
      NORTH=XNORTH
      WRITE(4,100) FRONT,EAST,NORTH,BACK
  100 FORMAT(A24,I8,I8,A32)
      GOTO 10
C
   20 CONTINUE
      STOP
      END
CTITLE GEOUTM GRID CONVERSION
      SUBROUTINE GEOUTM(LAT,LON,EAST,YNORTH)
C BASED ON THE TAS LANDS DEPT PROGRAM UTM
C THE EQUATIONS USED ARE FROM TM PROJECTION TABLES 1944.
C THE ORIGINAL FORMULAE AGREE WITH REDFEARNS FOR THE 1ST. AND
C 2ND. TERMS BUT DIFFER IN THE 3RD. TERM. HOWEVER TO IMPROVE
C ACCURACY THE FORMULA FOR NORTHING HAS BEEN CHANGED TO AGREE
C WITH REDFEARNS IN THE 3RD. TERM (Q3)
C CONVERTS FROM GEOGRAPHIC TO UTM COORDINATES
C INPUT IS LAT.LAT, LON.LON
C OUTPUT IS EAST COORDINATE,NORTH COORDINATE (DOUBLE PRECISION,METRES)
      DOUBLE PRECISION DEG,S,EAST,YNORTH,SIND,COSD,TAND,C,R,P,PC,PCC,
     . P1,P2,Q1,Q2,Q3,Q4,Q5,Q6,LAT,LON
      DEG=LAT
      S=111133.34878D00*DEG-16038.9546D00*DSIN(0.034906585D00*DEG)+
     . 16.8331D00*DSIN(0.0698132D00*DEG)-0.0218D00*DSIN(0.10472D00*DEG)
      DEG=0.01745329252D00*DEG
      SIND=DSIN(DEG)
      COSD=DCOS(DEG)
      TAND=(SIND/COSD)**2
      C=1.0D00-0.6694541855D-2*SIND**2
      R=6335461.141D00/C**1.5
      P=6378160.0D00/DSQRT(C)
      PC=P*COSD
      PCC=PC*COSD**2
      P1=(LON*3600.0D00
     .   -529200.0D00)*1.D-4
C 529200=147*3600 WHICH IS THE CENTRE OF ZONE 55 IN SECONDS
C FOR ZONE 54 (CENTRE=141 DEGREES) 141*3600=507600 ETC
C REF: THE  AUSTRALIAN MAP GRID - TECHNICAL MANUAL
C      NATIONAL MAPPING COUNCIL OF AUSTRALIA SPEC PUBLN 7
C      1972.  CALL NO 526.60994 NAT
      P2=P1**2
      Q1=1.D+7-0.9996D00*S
      Q2=PC*SIND*0.117475144D-2
      Q3=PCC*SIND*(4.0D00*(P/R)**2+P/R-TAND)*0.230099D-6
      Q4=PC*0.48461975563D-1
      Q5=PCC*(P/R-TAND)*0.18984519D-4
      Q6=PCC*COSD*COSD*(5.0D00-TAND*(18.0D00-TAND))*0.22311D-8
      EAST=500000.0D00+P1*(Q4+P2*(Q5+P2*Q6))
      YNORTH=Q1-P2*(Q2+P2*Q3)
      RETURN
      END
      SUBROUTINE GEOGRF(EAST,NORTH,LAT,LON)
      DOUBLE PRECISION NORTH,EAST,LAT,LON
      DOUBLE PRECISION TMD1,ORTH,DEG,TMD2,CON,Q1,DOG,SIND,COSD,
     . TAND,TANSQ,SINSEC,C,D,DTAN,R,P,PCUBE,POR,PFIVE,P1,P2,P3,P4,
     . P5,GLAT,TEMPL,DLONG,DC,SLO,SLA
      DOUBLE PRECISION VAL(16),Q(5)
      INTEGER*2 I,IDLA,MLA,IDLO,MLO
C CONVERTS AMG GRID COORDS (IN METRES) TO LATS AND LONGS
      VAL(1)=9.033D-06
      VAL(2)=1.1113334878D05
      VAL(3)=3.4906585D-02
      VAL(4)=6.981317D-02
      VAL(5)=1.04719755D-01
      VAL(6)=9.008D-06
      VAL(7)=1.745329252D-02
      VAL(8)=0.66945418546D-02
      VAL(9)=1.99840032D-08
      VAL(10)=23.96162303D-20
      VAL(11)=5.9928028794D-14
      VAL(12)=119.76019192D-26
      VAL(13)=2.9964014397D-14
      VAL(14)=14.970023989D-26
      VAL(15)=6.3354611409D06
      VAL(16)=1.60389546D04
C
      ORTH=NORTH
      TMD1=1.0D07-ORTH
      DEG=VAL(1)*TMD1
C
      DO 10 I=1,10
      TMD2=VAL(2)*DEG-VAL(16)*DSIN(VAL(3)*DEG)+
     . 16.83310D00*DSIN(VAL(4)*DEG)-0.0218D00*DSIN(VAL(5)*DEG)
      CON=TMD1-0.9996D00*TMD2
      IF (DABS(CON) .LT. 1.0D-03) GOTO 14
      DEG=DEG+VAL(6)*CON
   10 CONTINUE
      GOTO 16
C
   14 CONTINUE
      Q1=(EAST-500000.0D00)*1.0D-06
      Q(1)=Q1
      DO 11 I=2,5
      Q(I)=Q(I-1)*Q1
   11 CONTINUE
      DOG=VAL(7)*DEG
      SIND=DSIN(DOG)
      COSD=DCOS(DOG)
      TAND=SIND/COSD
      TANSQ=TAND*TAND
      SINSEC=0.48481368111D-05
      C=1.0D00-VAL(8)*SIND*SIND
      D=0.27777777778D01
      DTAN=D*TAND
      R=VAL(15)/C**1.5
      P=637816.0D01/C**0.5
      PCUBE=P**3
      POR=P/R
      PFIVE=PCUBE*P*P
      P1=DTAN/(VAL(9)*R*P*SINSEC)
      P2=DTAN*(5.0D00+3.0D00*TANSQ)/(VAL(10)*R*PCUBE*SINSEC)
      P3=D/(P*COSD*SINSEC*.9996D-02)
      P4=D*(POR+2.0D00*TANSQ)/(VAL(11)*PCUBE*SINSEC*COSD)
      P5=D*(5.0D00+TANSQ*(28.0D00+24.0D00*TANSQ))/(VAL(12)*
     .    COSD*PFIVE*SINSEC)
      GLAT=DEG-P1*Q(2)+P2*Q(4)
      TEMPL=P3*Q1-P4*Q(3)+P5*Q(5)
      DLONG=TEMPL+7.0D00
      LON=DLONG
      LON=LON+134
C 134 IS FOR ZONE 54.  VALUE IS ZONE CENTRE-7DEGREES.
C FOR ZONE 55 IS 140 DEGREES (CENTRE IS 147)
C ZONES ARE 6 DEGREES WIDE WITH 0.5 DEGREES OVERLAP ON EACH SIDE
C REF: THE AUSTRALIAN MAP GRID TECHNICAL MANUAL
C      NATIONAL MAPPING COUNCIL OF AUSTRALIA SPEC PULBN 7
C      1972.   CALL NO 526.60994 NAT
      LAT=GLAT
      GOTO 18
   16 CONTINUE
      WRITE(5,100)
  100 FORMAT(' ***************** GEOGRAPHICAL ERROR **************')
      STOP 9998
   18 CONTINUE
      RETURN
      END